Caffeinated

Sample Cakefile

Tue, 20 Mar 2012 12:59:00 -0700

Cake is the build tool for CoffeeScript. It's nifty, but the documentation is a little sparse. Here's an example Cakefile that does everything you need for a basic Coffee project:

{exec} = require 'child_process'


task 'test', 'Runs all Jasmine specs in spec/ folder', ->
  test()

task 'compile', 'Compiles coffee in src/ to js in bin/', ->
  compile()

task 'stitch', 'Stitches all app .js files', ->
  stitch()

task 'compress', 'Runs UglifyJS on stitched file in order to compress it', ->
  compress()

task 'build', 'Does the full build magic', ->
  test -> compile -> stitch -> compress()

task 'develop', 'Only compile and stitch, don\'t test or compress', ->
  compile -> stitch()


test = (callback) ->
  console.log "Running Jasmine specs"
  exec 'jasmine-node --coffee spec/', (err, stdout, stderr) =>
    console.log stdout + stderr

    # hack to work around jasmine-node's bad return vals:
    throw "Tests fail. Build fails. You fail." if ~stdout.indexOf "Expected"

    callback?()


compile = (callback) ->
  exec 'coffee -o bin/ -c src/', (err, stdout, stderr) ->
    throw err if err
    console.log "Compiled coffee files"
    callback?()


stitch = (callback) ->
  stitch = require 'stitch'
  fs = require 'fs'

  myPackage = stitch.createPackage paths: [__dirname + '/bin', __dirname + '/vendor']
  myPackage.compile (err, source) ->
    fs.writeFile 'app.js', source, (err) ->
      throw err if err
      console.log "Stitched js files"
      callback?()


compress = (callback) ->
  exec 'uglifyjs --overwrite app.js', (err, stdout, stderr) ->
    throw err if err
    console.log "Compressed app.js"
    callback?()

Project Structure

In this example, I'm using a project structure something like this:

That's all inside a "static" directory in a Django project, but it shouldn't matter what kind of server you're using. Coffee files are in src/, Jasmine specs are in spec/, and compiled JavaScript goes into bin/.

Dependencies

To run everything, you'll need Node (which you should have already if you're using CoffeeScript) and a few other things installed via npm:

stitch
uglifyjs
jasmine-node

You can run npm install -g to intall each of these system-wide.

Cake Tasks

Cakefiles are composed of tasks, which are defined at the top of the Cakefile like this:

task 'test', 'Runs all Jasmine specs in spec/ folder', ->
  test()

task 'compile', 'Compiles coffee in src/ to js in bin/', ->
  compile()

task 'stitch', 'Stitches all app .js files', ->
  stitch()

task 'compress', 'Runs UglifyJS on stitched file in order to compress it', ->
  compress()

task 'build', 'Does the full build magic', ->
  test -> compile -> stitch -> compress()

task 'develop', 'Only compile and stitch, don\'t test or compress', ->
  compile -> stitch()

Each of these tasks calls a function that performs the correct action. For example, the "compile" task calls this function:

compile = (callback) ->
  exec 'coffee -o bin/ -c src/', (err, stdout, stderr) ->
    throw err if err
    console.log "Compiled coffee files"
    callback?()

The reason I break the tasks out into functions like this is to make it easy to chain them together. Because Node runs processes asynchronously, I use callbacks in the functions instead of simply calling a sequence of tasks. If I just used "invoke", the full build would happen even if a Jasmine spec fails. Also, I just really like the way the full build task looks:

1 2	task 'build', 'Does the full build magic', -> test -> compile -> stitch -> compress()

Developing with Cake

Running cake with no arguments yields a list of tasks defined in the Cakefile.

Each step of the build has its own task, but I really only use three of them on a regular basis:

While coding, cake test lets me easily run Jasmine specs without waiting for compilation of CoffeeScript.
While testing small UI tweaks, cake develop lets me package things quickly for running in the browser without waiting for Uglify or Jasmine.
When I'm ready to deploy, cake build runs all the steps.

Caffeinated

Sample Cakefile

twitter.com UI fix

Moving stuff from old blog

Discovery

Scene from the Lyric Opera

Buy me this now

The First Two Weeks Back at School After Like Three Years of Not Being Anywhere Near as Busy as You Are During School and Mostly Forgetting How to Deal With It (i.e., Being Busy): A Retrospective

Minecraft

StarCraft 2 comes out tomorrow

Chipophone

Check it out

Flip Face-off

First movie experience

Shelob lives in my kitchen

A Cappella Zelda Theme

The Question Mark

Posterous